**3.14. Групповое изменение объектов**

Подсистема «Групповое изменение объектов» предоставляет пользовательский интерфейс для множественного изменения объектов одного типа. Помимо изменения реквизитов имеется возможность изменения дополнительных реквизитов и сведений (подсистема «Свойства»), если они есть у объектов.

Также подсистема учитывает наличие у объектов реквизитов, запрещенных для редактирования (подсистема «Запрет редактирования реквизитов объектов»).

**Настройка**

**Размещение команды изменения объектов в списках**

Сначала нужно принять решение по поводу состава объектов конфигурации, для которых должна быть добавлена команда по групповому изменению. Как правило, к таким объектам относятся большинство объектов конфигурации ссылочного типа.

Затем надо поместить команду для группового изменения объектов на командной панели и в контекстном меню формы списка. Рекомендуемые значения свойств команды:

Таблица 3.26.

|  |  |
| --- | --- |
| Свойство | Значение |
| Имя | ИзменитьВыделенные |
| Действие | ИзменитьВыделенные |
| Подсказка | Изменить выделенные объекты |
| Изменяет сохраняемые данные | Нет |

Также рекомендуется управлять видимостью команды в форме в зависимости от текущих прав пользователя. Например:

&НаСервере

Процедура ПриСозданииНаСервере(Отказ, СтандартнаяОбработка)

МожноРедактировать = ПравоДоступа("Редактирование", Метаданные.Справочники.\_ДемоНоменклатура);

Элементы.ФормаИзменитьВыделенные.Видимость = МожноРедактировать;

КонецПроцедуры

Установить у поля Ссылка основного реквизита формы признак Использовать всегда.

Добавить в модуль формы обработчик:

&НаКлиенте

Процедура ИзменитьВыделенные(Команда)

ГрупповоеИзменениеОбъектовКлиент.ИзменитьВыделенные(Элементы.Список, Список);

КонецПроцедуры

**Ограничение редактируемых реквизитов объектов**

Изменение некоторых реквизитов с помощью групповой обработки может быть нежелательным либо нарушать логику работы конфигурации. Такие реквизиты необходимо скрывать от пользователя.

Обработка группового изменения может быть вызвана как из формы списка для выбранных объектов, так и самостоятельно с последующим выбором изменяемых объектов в самой обработке, поэтому необходимо для всех объектов конфигурации рассмотреть необходимость ограничения доступности реквизитов для группового изменения.

Если для объекта метаданных определены реквизиты, которые можно изменять с помощью обработки группового изменения, следует объявить экспортную функцию РеквизитыРедактируемыеВГрупповойОбработке в модуле менеджера объекта, которая возвращает массив – имена реквизитов. При этом оставшиеся реквизиты скрываются в обработке группового изменения. В общем виде разрешенные для редактирования реквизиты объекта описываются следующим образом (пример см. в бизнес-процессе \_ДемоЗаданиеСРолевойАдресацией демонстрационной конфигурации):

// Возвращает реквизиты объекта, которые разрешается редактировать

// с помощью обработки группового изменения реквизитов.

//

// Возвращаемое значение:

//  Массив - список имен реквизитов объекта.

Функция РеквизитыРедактируемыеВГрупповойОбработке() Экспорт

РедактируемыеРеквизиты = Новый Массив;

РедактируемыеРеквизиты.Добавить("ИмяРеквизита"); // реквизит объекта

РедактируемыеРеквизиты.Добавить("ИмяТабличнойЧасти.ИмяРеквизита"); // реквизит табличной части объекта

РедактируемыеРеквизиты.Добавить("ИмяТабличнойЧасти.\*"); // все реквизиты табличной части объекта

РедактируемыеРеквизиты.Добавить("\*"); // все реквизиты и табличные части объекта

Возврат РедактируемыеРеквизиты;

КонецФункции

Если стоит обратная задача: известны имена реквизитов, которые не должны редактироваться в обработке группового изменения, – следует объявить в модуле менеджера объекта функцию РеквизитыНеРедактируемыеВГрупповойОбработке, которая возвращает массив – имена реквизитов (аналогично функции РеквизитыРедактируемыеВГрупповойОбработке). Пример см. в справочнике \_ДемоНоменклатура демонстрационной конфигурации.

Если объект не предназначен для использования в групповом изменении, то необходимо скрывать все его реквизиты.

Важно!

Служебные реквизиты объектов, такие как Ссылка, Наименование, ПометкаУдаления и т. д., а также некоторые табличные части не требуют дополнительных действий для скрытия в обработке группового изменения, так как они скрыты по умолчанию. Подробнее со списком таких реквизитов и табличных частей можно ознакомиться в макете ФильтрРеквизитов обработки ГрупповоеИзменениеОбъектов.

При необходимости также следует перенести логику проверки заполнения объектов и логику «при записи» из модулей форм в модули объектов.

Все объекты метаданных, в которых определены функции РеквизитыРедактируемыеВГрупповойОбработке и РеквизитыНеРедактируемыеВГрупповойОбработке, следует перечислить в процедуре ПриОпределенииОбъектовСРедактируемымиРеквизитами общего модуля ГрупповоеИзменениеОбъектовПереопределяемый.

**Настройка прав доступа пользователей**

Таблица 3.27.

| № | Роли и их назначение |
| --- | --- |
| 1. | ПолныеПрава  Редактирование любых объектов конфигурации (при открытии формы группового изменения реквизитов из раздела командного интерфейса «Администрирование») |
| 2. | Другие роли  Для группового изменения реквизитов в списках объектов не требуются какие-либо дополнительные роли. Эта возможность будет доступна, если у пользователя есть права на редактирование самих объектов |

**Настройка обмена данными**

Для настройки обмена данными никаких действий не требуется, так как подсистема не предоставляет собственных данных.